#name 洛小舟紫霞超级宏2.5
#Hello 欢迎$name使用此气纯宏，希望此宏能给你带来最大的DPS提升。
#tip 这只是一个追求DPS的羊慢慢琢磨的宏，尽善尽美，奥妙全在细微之处！
#icon 3119
#delay 1
#varnum v_爆发模式,4,tip_1:1.腰坠和韬光养晦绑定的爆发模式,Icon_1:2930,tip_2:2.没有特效腰坠的爆发模式,Icon_2:625,tip_3:3.半手动爆发（紫气连带）,Icon_3:2943,tip_4:4.全手动爆发,Icon_4:3587
#varbool v_切换加速,Icon:2033,tip:非连续读条GCD切换加速装备赚取收益
#varbool v_切换会破,Icon:3553,tip:紫气爆发高会心时切换纯破防暗器
#varbool v_切换武器,Icon:3406,tip:切换雷特效武器（兼容405-485）
#varbool v_气场范围,Icon:1449,tip:对自身下破苍穹,off
#varbool v_蓝药回蓝,Icon:1361,tip:抱元守缺CD和没鼎下使用大蓝药回蓝,off
#skillbox 抱元守缺,三才化生,九转归一,破苍穹,凭虚御风:off,扶摇直上:off
/say [fight<2,(tname:木桩|木小呆|木武童;tar:boss)]s,吾心腾空踏幽云，卧舟画影断冷月
–凭虚减仇恨–
/skill [(fight<10;threat>0.9),!buff:引羌笛|极乐|金刚伏魔五阵]凭虚御风
–参数赋值–
/if [ota:四象轮回>(0.9-ping/gcdt),nav>6]
/var [now]v_ynav
/var [true]v_nav
/end
/if [now-v_ynav>0.1+ping]
/var [false]v_nav
/end
/var [(!cd:万世不竭;cdtime:万世不竭<0.5),(nav>7;v_nav)] v_w
/var [cdtime:万世不竭>0.5,(nav>8;v_nav;buff:韬光养晦,nav>=7)] v_2
/var [cdtime:万世不竭>0.3,nav<9;(cdtime:万世不竭<0.5;!cd:万世不竭),(nav<7,nav>4,!lastota:四象轮回);cdtime:万世不竭<0.5,nav<5;nav<5;dis>=21]v_4
/var [cd:万世不竭;buff:韬光养晦,nav<9]v_t
/var [buff:破苍穹,(banskill:破苍穹;sklv:破苍穹=0;!banskill:破苍穹,auro:破苍穹>12),tmbuff:气竭=3] v_b
/var [tname:木桩|木小呆|木武童;tar:boss]v_tg
–气场选择–
/if[v_气场范围]
/skill [tarisem,!ota:破苍穹]targetsave
/skill [ota:破苍穹]targetself
/skill [gcd=0,cdtime:破苍穹>7]targetread
/end
–扶摇模式–
/skill [v_4]扶摇直上
–切换装备–
/if[v_切换加速]
/if[(lastcast:两仪化形|破苍穹|抱元守缺|太极无极,(v_4;v_w),ggcd<1;!fight),!ota:四象轮回|万世不竭,(!buff:1916;bufftime:1916<=1.5),!buff:韬光养晦]
/omwp 疑花接木,栎暮囊 –需依照自己装备修改加速武器/暗器
/else
/equip [v_切换会破,!buff:紫气东来|4759]若尘囊,玉叶囊,钦化囊
/equip [v_切换会破,buff:紫气东来|4759]碎曳囊,凌冬囊,廷中
/omwp [v_切换武器,!buff:6394]水玉长生剑,钧灵品
/omwp [v_切换武器,buff:6394]含元剑,志齐青云,灵虚大菜刀·火候,青陌剑,哲惟剑
/equip [!v_切换会破]钦化囊 –需依照自己装备修改自身暗器
/omwp [!v_切换武器]含元剑 –需依照自己装备修改自身原有武器
/end
/elseif[!v_切换加速]
/equip [v_切换会破,!buff:紫气东来|4759]若尘囊,玉叶囊,钦化囊
/equip [v_切换会破,buff:紫气东来|4759]碎曳囊,凌冬囊,廷中
/omwp [v_切换武器,!buff:6394]水玉长生剑,钧灵品
/omwp [v_切换武器,buff:6394]含元剑,志齐青云,灵虚大菜刀·火候,青陌剑,哲惟剑
/end
–八卦打断–
/skill [tprepare:餐风饮露|噬血影|净与无净|一阳指·二品|无懈可击|天音化物|雨钓江秋|龙甩尾|怒吼|急行军|火舞金刚|绞喉]八卦洞玄
–QTE功能–
/skill QTE
–抱元蓝药–
/use [v_蓝药回蓝,mana<0.1,cd:抱元守缺]尚·上品活络丹 –或修改为自己的蓝药
/skill [mana<=0.06,nav>7,!lastota:万世不竭]抱元守缺
/skill [mana<=0.4,v_2,(!buff:紫气东来|风·灭气|1916;bufftime:1916<=1.5;bufftime:韬光养晦<=1.5)]抱元守缺
–特效判定–
/skill [buff:1916,bufftime:太极>=3,tmbufftime:气竭>=3;tlifeleft<100000,(nav>8;v_nav)]两仪化形
–破苍穹气场–
/skill [tlife>0.06,(!buff:破苍穹;aurotime:破苍穹<1.5;(((v_爆发模式=1;v_爆发模式=2),cdtime:紫气东来<1;v_爆发模式=1,icdtime:灵南坠<1),v_tg,tmbuff:气竭=3,aurotime:破苍穹<12)),!buff:紫气东来|韬光养晦|风·灭气|1916,(!tmbuff:气竭;tmbufftime:气竭>=3),(!buff:太极;bufftime:太极>=3)]破苍穹
–爆发模式–
/if [v_爆发模式=1,v_tg,distance<=20]
/skill [v_w,v_b] 紫气东来
/skill [buff:风·灭气|紫气东来,nav<6]韬光养晦
/use [v_w,v_b]灵南坠
/end
/if [v_爆发模式=2,v_tg,distance<=20]
/skill [v_w,v_b] 紫气东来
/skill [(buff:紫气东来;cd:紫气东来,cdtime:紫气东来>10),nav<6]韬光养晦
/end
/if [fight,v_爆发模式=3]
/skill [buff:紫气东来,nav<6]韬光养晦
/use [buff:紫气东来]灵南坠
/end
–输出循环–
/skill [v_w]万世不竭
/skill [v_2]两仪化形
/skill [v_t]太极无极
/skill [v_4]四象轮回
/skill [fight,cd:两仪化形|太极无极]九转归一
/skill [fight,cd:两仪化形|太极无极,distance<8]三才化生
/skill [fight]三柴剑法
–移动项–
/skill [state:run|jump,nav>7]两仪化形
/skill [state:run|jump]太极无极,破苍穹
–破苍穹气场–
/if [tlife>0.06,(tname:木桩|木小呆|木武童;tar:boss)]
/skill [(!buff:破苍穹;!aurotime:破苍穹;aurotime:破苍穹<1.5;(v_爆发模式=1;v_爆发模式=2),aurotime:破苍穹<12,cdtime:紫气东来<1;v_爆发模式=1,aurotime:破苍穹<12,icdtime:灵南坠<1),!buff:紫气东来|韬光养晦|风·灭气|1916]破苍穹
/elseif [tlife>0.06]
/skill [(!buff:破苍穹;!aurotime:破苍穹;aurotime:破苍穹<1.5),!buff:紫气东来|韬光养晦|风·灭气|1916]破苍穹
/end
–爆发模式–
/if [v_爆发模式=1,fight,(tname:木桩|木小呆|木武童;tar:boss),distance<=20]
/if [!banskill:破苍穹]
/skill [(icdtime:灵南坠<1,cdtime:破苍穹>2,buff:破苍穹,lastcast:两仪化形|万世不竭;buff:风·灭气),nav<5]韬光养晦
/skill [buff:韬光养晦;(cdtime:破苍穹>2,buff:破苍穹;auro:破苍穹>11),nav>7,ggcd<0.5]紫气东来
/use [buff:韬光养晦;(cdtime:破苍穹>2,buff:破苍穹;auro:破苍穹>14),nav>7,ggcd<0.5]灵南坠
/end
/if [banskill:破苍穹;sklv:破苍穹=0]
/skill [(icdtime:灵南坠<1,buff:破苍穹,lastcast:两仪化形;buff:风·灭气),nav<5]韬光养晦
/skill [buff:韬光养晦;buff:破苍穹,nav>7,ggcd<0.5]紫气东来
/use [buff:韬光养晦;buff:破苍穹,nav>7,ggcd<0.5]灵南坠
/end
/end
/if [v_爆发模式=2,fight,(tname:木桩|木小呆|木武童;tar:boss),distance<=20]
/if [!banskill:破苍穹]
/skill [nav<5,cdtime:破苍穹>2,buff:破苍穹,lastcast:两仪化形]韬光养晦
/skill [buff:韬光养晦;(cdtime:破苍穹>2,buff:破苍穹;auro:破苍穹>11),nav>7,ggcd<0.5]紫气东来
/end
/if [banskill:破苍穹;sklv:破苍穹=0]
/skill [nav<5,buff:破苍穹,lastcast:两仪化形]韬光养晦
/skill [buff:破苍穹,nav>7,ggcd<0.5;buff:韬光养晦]紫气东来
/end
/end
/if [fight,v_爆发模式=3]
/skill [buff:韬光养晦]紫气东来
/use [buff:韬光养晦]灵南坠
/end
