#name 一杯橙汁的大师宏
#tip 『一杯橙汁』的大师宏，v0.3.4a ╮(￣▽￣”)╭ n●”踏云”技能点亮则30%以下不开金刚,关闭则全程保持金刚怒目 n●奇穴：[涅果][妙法][业力][幻身][降魔渡厄][金刚怒目][三生][明法][心棍][众嗔]
#icon 5310
#delay 1
#hello n逗比$name：n记得每天去做茶馆大战门派日常，做完记得交任务。。 n本宏需要<超级宏插件1.2.0版>或更高n ╮(￣▽￣”)╭ n
#varbool v_yz,tip:特效腰坠,icon:2841,tip_1:使用腰坠,tip_2:不使用腰坠
#varnum v_js,3,tip:减伤模式·右键菜单,icon:436,tip_1:只用无相诀,tip_2:无相+锻骨,tip_3:关闭减伤,icon_1:422,icon_2:421,icon_3:-2590
#varnum v_bf,3,tip:爆发模式·右键菜单,icon:445,tip_1:擒龙+金刚,tip_2:只用金刚怒目,tip_3:关闭爆发,icon_1:445,icon_2:440,icon_3:-2590
#varbool v_zdhc,tip:自动后撤,tip_1:开启自动后撤,tip_2:关闭自动后撤,icon:1491
#varnum v_zdfy,3,tip:自动扶摇·右键菜单,icon:1485,tip_1:智能扶摇,tip_2:全程扶摇,tip_3:手动扶摇,icon_1:1485,icon_2:622,icon_3:-2590
#varnum v_dz,4,tip:智能辅助·右键菜单,icon:2049,tip_1:大战辅助,icon_1:593,tip_2:剑圣划水,icon_2:2874,tip_3:风雪稻香村&秦皇陵,icon_3:5942,tip_4:关闭辅助,icon_4:-2590
#varbool v_mb,tip:目标,off,icon:2965,tip_1:开启,tip_2:如果不知道这是什么请保持关闭
#varnum v_wq,4,tip:换武器·右键菜单,icon:4779,tip_1:雷+普,icon_1:3406,tip_2:水+普,icon_2:3412,tip_3:水+雷+普,icon_3:3407,tip_4:关闭换武器,icon_4:-2590
#varbool v_qte,tip:自动QTE,off,tip_1:开启一键QTE,tip_2:关闭一键QTE,icon:331
#skillbox 亦枯亦荣,横扫六合,般若诀:off,摩诃无量:off,捕风式,捉影式,拿云式,打坐:off,踏云

– **** ↓ 减伤 ↓ ****
/if [fight,nobuff:渊&镇山河&春泥护花&圣手织天&蝶戏水&天地低昂&舍身]
/skill [(v_js=1;v_js=2),life<0.4] 无相诀
/skill [(v_js=1;v_js=2),mapc:血战天策,tprepare:狼之怒|藏离精失] 无相诀
/skill [v_js=2,(buff:步迟|破云枪|击晕;tprepare:云烟卷>0.6)] 锻骨诀
/end
– **** ↓ 扶摇+后撤+QTE ↓ ****
/skill [v_qte] QTE
/skill [v_zdhc,nobuff:镇山河,(tprepare:掷锤>0.5;(tprepare:力拔千钧>0.7,distance<10);(tprepare:吞云吐纳>0.7,distance<8);tprepare:泰山压顶>0.8)] 后撤
/skill [v_zdfy=2;(v_zdfy=1,fight,((mapc:大明宫,(((target:安禄山,(tlife>0.7;tlife<0.12)));(buff:追击);(target:头狼);(target:无名,tbuff:白昼);(target:独孤问俗,(tlife<=0.1;buff:沙暴))));(mapc:秦皇陵,target:王翦,tlife>=0.5,tlife<=0.82);(mapc:风雪稻香村,tplate:地字一号,tlife<=0.3);(mapc:军械库,target:萧沙|澹台枯火,distance<10);(mapc:直城门,target:阿史那承庆,tprepare:枪兵令);(mapc:荻花圣殿,target:卫栖梧,tprepare:飞云回转刀);(mapc:琉璃岛,target:詹素);(mapc:血战天策,((tplate:沙叱博,(tlife<0.31;tlife>0.7,tlife<0.72),tprepare:狼之怒);buff:火星))))] 扶摇直上
/cbuff [v_zdfy=1,mapc:血战天策,tplate:席庶云,buff:弹跳,tprepare:云烟卷] 弹跳
– **** ↓ 减仇恨 ↓ ****
/skill [sklv:佛心诀=1,fight,nobuff:九襄地玄五阵&金刚伏魔五阵&引羌笛&极乐,sktest:佛心诀] 佛心诀
– **** ↓ 打断 ↓ ****
/skill [sklv:抢珠式=1,tprepare,sktest:抢珠式] 抢珠式
– **** ↓ 变量 ↓ ****
/var [nav] v_nav
/var [sktest:普渡四方;(target:傀儡·天,distance<=6);distance<=5] v_distance
– **** ↓ 换武器 ↓ ****
/if [fight]
/omwp [v_wq=1,nobuff:6394,v_nav<3,nobuff:6360,bag:寂净谛观|独悟空山] 寂净谛观,独悟空山
/omwp [(v_wq=4;v_wq=1,(buff:6394|6360;nobuff:6394,v_nav>=3)),bag:白塔思|禅机棍|殷武棍|八道皆攻] 禅机棍,白塔思,殷武棍,八道皆攻
/omwp [v_wq=2,(nobuff:水·痛切;(buff:水·痛切<=10;bufftime:水·痛切<=5)),gcdt/2+ping>=ggcd>=ping,bag:禅心伏明] 禅心伏明
/omwp [v_wq=2,buff:水·痛切,bufftime:水·痛切>2,bag:禅机棍] 禅机棍
/if [v_wq=3]
/omwp [(nobuff:水·痛切;(buff:水·痛切<=10;bufftime:水·痛切<=5)),gcdt/2+ping>=ggcd>=ping,bag:禅心伏明] 禅心伏明
/omwp [nobuff:6394,v_nav<3,buff:水·痛切,bufftime:水·痛切>2,bag:寂净谛观|独悟空山] 寂净谛观,独悟空山
/omwp [(nobuff:6394,v_nav>=3;buff:6394),buff:水·痛切,bufftime:水·痛切>2,bag:禅机棍] 禅机棍
/end
/end
– **** ↓ 剑圣划水 ↓ ****
/if [v_dz=2,fight,tplate:剑圣,mapc:大明宫]
/skill [v_nav=3] 金刚怒目
/skill [v_nav<3,(nocd:金刚怒目;cdtime:金刚怒目<=ggcd),buff:捕风式] 捉影式
/skill [v_nav<3] 捕风式
/return [tplate:剑圣,mapc:大明宫]
/elseif [v_dz=3,mapc:风雪稻香村|秦皇陵]
/skill [tplate:地字一号,tbuff:7310,distance<=8,sktest:8674,tmfront] 8674 –盘龙卧山
/skill [tplate:隐元会暗杀者,distance<=20,sktest:8673,tmfront,tnobuff:7644] 8673 –千索夺魂
/skill [tplate:隐元会暗杀者,distance<=16,sktest:8676,tmfront] 8676 –寒冰针枪
/use [bag:74368,tplate:30353,!tstate:stand] 74368 –停车
/tab [tprepare<0.7,tplate:隐元会暗杀者,tmfront,tnobuff:7644] npc,dismin
/skill [tprepare<0.7,buff:捕风式,sktest:捉影式,tplate:隐元会暗杀者,!sktest:8673] 捉影式
/skill [distance<=20,tplate:隐元会暗杀者,!sktest:8673] 捕风式
/end
– **** ↓ 爆发 ↓ ****
/skill [v_bf=1,v_nav<=1,v_distance,(bufftime:金刚怒目>7;tlife<0.3),ggcd<gcdt-1,nocd:擒龙诀] 亦枯亦荣,擒龙诀
/var [explast:擒龙诀,3;v_nav] v_nav
/skill [(banskill:踏云;!banskill:踏云,tlife>0.3),tarisem,(v_bf=1;v_bf=2),v_nav>=3,sktest:守缺式,cdtime:金刚怒目<ping,nobuff:1919] 金刚怒目
/var [explast:金刚怒目,0;v_nav] v_nav
/skill [(buff:擒龙诀&金刚怒目;!banskill:踏云,tlife<0.3),v_yz] 腰坠
– **** ↓ 回蓝 ↓ ****
/skill [v_nav=1,mana<0.2,fight,tlife<1,sktest:守缺式,tnobuff:5700] 亦枯亦荣
/var [explast:亦枯亦荣,0;v_nav] v_nav
– **** ↓ 输出部分 ↓ ****
/skill [fight,v_distance,!target:boss,nobuff:擒龙诀,cdtime:摩诃无量<ping] 摩诃无量
/skill [(buff:众嗔<5;buff:众嗔=5,bufftime:众嗔<3),cdtime:守缺式<ping] 守缺式
/skill [v_nav>=3,cdtime:拿云式<ping,(sklv:5899<1;sklv:5899>0,emdis:6<2)] 拿云式
/skill [v_nav>=3,sklv:5899>0,emdis:6>1,cdtime:韦陀献杵<ping] 韦陀献杵
/skill [v_nav>=3,(!sktest:拿云式;banskill:拿云式),cdtime:韦陀献杵<ping] 韦陀献杵
/var [explast:拿云式|韦陀献杵,1;v_nav] v_nav
/skill [sklv:5915>0,cdtime:守缺式<ping] 守缺式
/skill [fight,tarisem,v_distance] 横扫六合
/skill [sklv:6578>0,cdtime:守缺式<ping] 守缺式
/var [sklv:6578>0,explast:守缺式,v_nav+1;v_nav] v_nav
/skill [buff:擒龙诀,v_nav<=2;v_nav<3] 普渡四方
/var [explast:普渡四方,v_nav+1;v_nav] v_nav
/skill [fight>5,(buff:擒龙诀,v_nav<1;nobuff:擒龙诀,v_nav<2),(buff:捕风式,gcdt>ggcd>ping;ggcd>0.44+ping,state:stand),sktest:捉影式,!tplate:隐元会暗杀者] 捉影式
/var [explast:捉影式,v_nav+1;v_nav] v_nav
/skill [tar,sktest:捕风式,(!sktest:守缺式;cdtime:守缺式>gcdt)] 捕风式
/var [explast:捕风式,v_nav+1;v_nav] v_nav
/skill [tar,sktest:捕风式,state:jump,buff:弹跳] 千斤坠
– **** ↓ 目标 ↓ ****
/if [fight,v_mb]
/if [tar,!tarisem;taristm;tarisem,distance>20]
/skill targetnil
/elseif [notar;tarisem,!tmfront]
/tab [tarisem,tmfront,distance<=20] npc,dismin
/end
/end
– **** ↓ 杂项 ↓ ****
/skill [(nobuff:般若诀;bufftime:般若诀<300),nobuff:1919,nobuff:金刚怒目&擒龙诀] 般若诀
/if [v_dz=1,mapc:直城门,nofight,target,distance<=24]
/use [target:好赌的狼牙兵,tnobuff:6690,bag:74027] 74027
/use [target:贪吃的狼牙兵,tnobuff:6587,bag:74026] 74026
/use [target:嗜酒的狼牙兵,tnobuff:6586,bag:74025] 74025
/elseif [v_dz=1,mapc:流离岛,nofight]
/return [ota]
/use [buff:5906,bag:72688,state:stand] 72688
/dia [target:郑毅,!bag:72688] 请再
/elseif [v_dz=1,mapc:华清宫,nofight,buff:5252]
/dia [target:华清宫守卫,diaex] 十三，竹子，小钟
/elseif [v_dz=1,mapc:华清宫,nofight,!v_5252]
/var [buff:5252] v_5252
/use [nobuff:5252,bag:71734,state:stand] 71734
/dia [target:王三金,!bag:71734] 获取
/elseif [v_dz=1,mapc:一线天,nofight]
/dia [target:郭氏护卫统领,distance<6] 我等,去路,如何
/end
/if [nofight,!banskill:打坐]
/skill [(life<1;mana<1;nav<3),nobuff:调息] 打坐
/cbuff [life=1,mana=1,buff:调息,nav=3,sprint=1] 调息
/end
–[伊悲铖芷@幽月轮][一轮明月一归舟]