焚影超级宏 by 跃冰
云端ID 2931 作  者 最近更新20140703 代码类型超级宏 本周热度437 作者专栏

享受你们最后的时光吧！

 

3.27版本6月16日发布，需要1.21版本插件

这次真的是该版本最后一次更新了，下次将更新新架构宏代码

 

请在使用本宏仔细阅读以下说明

 

本宏自带QTE功能，不要问我为什么没开关了，不需要开关

奇穴选择和秘籍选择请仔细阅读本页面下方的推荐方案说明，因秘籍不对而无法达到最佳输出效果本人概不负责且不接受询问

吸血T不能用这个宏，明尊完全不一样的奇穴在这个宏里很多判定都是失效的，想吸血T用明尊宏

这是明尊宏链接：http://www.jx3pve.com/cloud/3006

 

1. 默认智能循环说明

当前版本默认为日月混合循环，循环目标为最大化利用双斩CD，交替打日系和月系

但是针对阴性和阳性的易伤目标会自动切换成纯日和纯月，不再刻意维持加速buff和灼烧

针对群怪场合(需要【日月凌天】奇穴)，攻击范围内超过3个怪自动进入纯日群怪模式，绕好背打出同辉加速buff最多断两秒

选择【无往不复】奇穴时，不会对多目标转换成纯日模式，而是维持混合模式循环

刻意保加速反而群不高

2. 单点禁群开关说明

在点出洞若观火奇穴的情况下，开关切换到单点禁群后只会使用烈日斩，银月斩，幽月轮三个技能，适用于曹炎烈开场和转阶段；对于10黑鹰这种boss建议洗掉洞若观火奇穴，这样在这个模式下会以纯月循环输出，同辉满日时自动使用生死劫

3.智能扶摇说明

地字一号和王翦的自动挂扶摇已经加入，之前的boss挂扶摇基本没变，需要注意的是雷狼的狼之怒是看到读条后挂，32%血提前挂，并且在此期间不会因为血量不足贪魔体导致你跳不起来的

新增，雷狼读条后若扶摇CD并且没弹跳buff，会开贪魔体保命，否则自动炸掉贪魔体挂扶摇，保证能跳起来

4.武器切换开关说明

武器名字全部都有了。。。。不需要的自己删掉多余的就好。。。包里没有的武器不删不影响

切换模式支持雷-普通，水-普通，普通-水-雷，雷-水，武器名字请不要敲错

最近更新后水特效武器卡最后一秒切，松哥说不会断的放心好了

补丁区有卡gcd切武器补丁，可用于替换主宏的换武器模块，有需要尝试卡gcd切的自行替换，可修改提前量数值，为整数，范围1-6，建议值2-3，平砍命中率低断层风险较高，但可以保证技能攻击全部不用水特效武器

5. 生死劫月开关

六道天连线阶段和天狼连线阶段自行开启，防止月破前冲

开启后输出循环自动变为纯日

6.腰坠开关

本宏的自动腰坠配合天地流的驱夜，生灭流的生灭，以及雷特效/朝圣言/大旗中任意一个条件使用，不针对特定BOSS的易伤阶段，有需要请请手动开

7.技能开关

隐身光明相生灭开关不解释了，关了就禁用并且循环中排除对其的考虑，迎风回浪开关同时是自动后跳开关

贪墨体开关注意，打开开关状态下，血量过低自动减伤，并且在血量回到70%以上自动取消，战斗中关闭开关附带立即取消贪魔体效果 

8.其他补丁说明

换项链和腰坠的补丁和换武器一样自行修改装备名称

CW补丁只是补丁，不保证最佳效果，相对与没补丁的效果只是特效触发之后无视其他爆发技能直接利用驱夜和月系技能满灵打破魔

 

 

如有技能循环上的bug请在QQ群321292064反馈,进群请再三思量，群里都是蛇精病

最近更新频繁图片编辑起来比较麻烦，所以先去掉了。。。

 

奇穴点法- 收起

单体BOSS:
生灭流：【腾焰飞芒】【无往不复】【洞若观火】【辉耀红尘】【明光恒照】【无明业火】【寂灭劫灰】【无量秒境】【生灭予夺】【日月同辉】
天地流：【腾焰飞芒】【无往不复】【洞若观火】【辉耀红尘】【明光恒照】【无明业火】【寂灭劫灰】【无量秒境】【天地诛戮】【日月同辉】
银月斩若溢出，第一奇穴改为【无幽不蚀】
需要群怪场合：
【无幽不蚀】【日月凌天】【洞若观火】【辉耀红尘】【明光恒照】【无明业火】【寂灭劫灰】【无量秒境】【生灭予夺】【日月同辉】

秘籍搭配- 收起

天地流幽月轮3本会心1本伤害，生灭流幽月轮3本会心1本额外回5点月魂
烈日斩静止目标10%伤害，4%会心，4%5%伤害
赤日轮破魔驱夜均可选择2本伤害2本会心
银月斩3本会心1本加月魂

急速阈值- 收起

刚到90的新手可选二档92
当前版本推荐三档509
血战毕业进军秦皇陵和风雨稻香村可选四档990
<一定要点这复制宏代码> 
  1. #name 焚影_跃冰版
  2. #icon 4191
  3. #tip version 3.27 \n适用于逐日中原版本 \n本宏仅用于焚影输出场合，请勿用于明尊心法\n 明尊吸血T大战请使用明尊宏http://www.yylmacro.com/cloud/3006 谢谢合作！
  4. #hello $name，欢迎使用跃冰版焚影输出宏
  5. #delay 1
  6. #skillbox 暗尘弥散,光明相,3978,迎风回浪,贪魔体
  7. #VarNum v_循环选择,2, tip:循环选择|自动选择|单点禁群, icon:3809|3809|3808
  8. #VarNum v_扶摇模式,3,tip:扶摇模式|智能模式|全程保持|关闭扶摇,icon:1485|1485|622|-1485
  9. #VarNum v_h,5,tip:换武器(自行修改武器名)|关闭|雷特效|水特效|三刀切换|雷水切换,icon:3849|3849|3947|3971|3948|3973
  10. #VarNum v_月劫,2,tip:生死劫月开关|关闭(默认)|打开(防前冲), icon:3867|-3867|3867
  11. #VarBool v_腰坠开关, icon:2841
  12. ---------------------------奇穴检查-----------------------------------------
  13. /var [fight, v_ct] v_ct
  14. /var [fight, !v_ct] v_uct
  15. /if [v_uct]
  16. /if [mount:焚影圣诀,(sklv:6725=0;sklv:5968=0;sklv:6717=0)]
  17. /print [string:你是不是忘了换奇穴啊]
  18. /end
  19. /var [sklv:3978=1] v_生灭
  20. /var [sklv:3961=1] v_寒月耀
  21. /if [v_生灭,sklv:6722=1,recipe:幽月轮人偶图残页]
  22. /var [sklv:5971=1,1;sklv:5970=1,2;0] v_ltsm
  23. /else
  24. /var [0] v_ltsm
  25. /end
  26. /var [sklv:煌日照=1] v_煌日照
  27. /end
  28. /var [v_uct;v_ct] v_ct
  29. /var [sktest:4326] v_dis4
  30. /return [ota;mount:10243]
  31. ----------------------------------------------------------------------------
  32. --换项链补丁插入位置
  33. --------------------------------换武器-------------------------------------
  34. /omwp [(v_h=3;v_h=4,buff:6394),bufftime:4761>=1,buff:4761=10;v_h=2,buff:6394] 乙明弯刀,彭蠡双刀,妙火天香串·火候,丙炎弯刀,圆缺双刀,霍致殇,明煌,黄泉刀,蹲循双刀,志吟双刀,大首领,澄辉双刀,惟清·木缪双刀,裁罪,雉于飞,月蚀·陟帝双刀 --普通武器
  35. /omwp [v_h>2,(bufftime:4761;0)<1] 枭心之戮  --水特效武器
  36. /omwp [v_h=2,nobuff:6394;v_h>3,bufftime:4761>=1,buff:4761=10,(nobuff:6394;v_h=5)] 凌冥思,清风断川,绝远袂,蜂蝶休猜,月重轮,开函谷  --雷特效武器
  37. /skill [0<bufftime:4761<gcdt,gcd=0,dis>6,cd:银月斩,fight] 虹气长空
  38. ----------------------------生存和副本订制----------------------------------
  39. /skill [fight,(life<0.3;1<bufftime:火星<3),nobuff:渊&镇山河&春泥护花&圣手织天&蝶戏水&天地低昂&舍身,nostate:jump&float,tnopre:骨牢|皇之怒|狼之怒|藏离精失;state:stand|run,tpre:狼之怒|藏离精失,cdtime:9002>gcdt>gcd,nobuff:弹跳] 贪魔体
  40. /delbuff [nobuff:火星,life>0.7,tnopre:狼之怒|藏离精失;tpre:狼之怒|藏离精失,(buff:弹跳;nocd:9002);banskill:贪魔体] 贪魔体
  41. /delbuff [existnpc:阿史那从礼<20,mapc:血战天策] 弹跳
  42. /delbuff [tname:令狐伤,mapc:血战天策] 袖气,清心静气,撼如雷,般若诀
  43. /if [v_扶摇模式=2,!existnpc:阿史那从礼<20]
  44. /skill 9002
  45. /end
  46. -----------------------------------------------------------------------------
  47. /skill QTE
  48. /return [notar;!tarisem;tname:？？？|追命箭矢;tbuff:金蛇盘巢]
  49. --------------------------------后跳-----------------------------------------
  50. /if [!banskill:迎风回浪]
  51. /skill [nobuff:镇山河,ggcd<0.2,(tpre:吞云吐纳>0.6,nocd:流光囚影;tpre:骨牢>0.6)] 迎风回浪
  52. /skill [nobuff:镇山河,(cdtime:迎风回浪>gcd>0.3;cd:流光囚影),tpre:吞云吐纳>0.7] 后撤
  53. /skill [nobuff:镇山河,tpre:掷锤>0.5;tpre:封岳>0.2,dis<4] 后撤
  54. /end
  55. ----------------------------日月选择----------------------------------------
  56. /var [v_循环选择=2,sklv:5978=1;tbuff:7423] v_banfull
  57. /var [cdtime:烈日斩] v_scd
  58. /var [cdtime:银月斩] v_mcd
  59. /var [tbuff:5629;buff:4309|5574;v_循环选择=2] v_pmoon
  60. /var [tbuff:5626;v_月劫=2;temdis:4>1,moon<sun+30,!(tname:独孤问俗,tlife<0.4),sklv:5971=1] v_psun
  61. /if [v_pmoon;sun<moon]
  62. /var [1] v_cycle
  63. /elseif [v_psun;moon<sun;(tbuff:1928,tnobuff:7683),bufftime:急月>8*gcdt]
  64. /var [2] v_cycle
  65. /else
  66. /if [v_scd<3*gcdt;v_mcd<3*gcdt]
  67. /var [v_scd<=v_mcd,2;v_mcd<v_scd,1] v_cycle
  68. /else
  69. /var [(bufftime:急月,0)>=(tmbufftime:灼烧,0),2;1] v_cycle
  70. /end
  71. /end
  72. -----------------------------------------------------------------------------
  73. --程武补丁插入位置
  74. ----------------------------------无GCD部分----------------------------------
  75. /if [!banskill:暗尘弥散,nocd:暗尘弥散,!v_banfull]
  76. /var [v_dis4,nobuff:暗尘&暗尘弥散&诛戮,0.2<cdtime:驱夜断愁<=gcd<0.45,sun<80,moon<80] v_隐身
  77. /var [!v_生灭,buff:日月灵魂=7,bufftime:日月灵魂>4] v_天地推迟同辉
  78. /else
  79. /var [false] v_隐身
  80. /var [false] v_天地推迟同辉
  81. /end
  82. /if [!banskill:光明相,nocd:光明相,!v_banfull]
  83. /var [v_dis4,fight,gcd<0.4,(buff:日月灵魂;0)<7,nobuff:日月同辉&生灭予夺&乐渡&4930,(v_生灭;buff:诛戮;banskill:暗尘弥散;!v_生灭,cd:暗尘弥散>15)] v_光明相
  84. /else
  85. /var [false] v_光明相
  86. /end
  87. /if [v_生灭,!banskill:3978,!v_banfull,tlifeleft>3000000]
  88. /var [v_dis4,nobuff:日月同辉&暗尘弥散,(buff:日月灵魂;0)<6,buff:无明业火>2] v_生灭予夺
  89. /end
  90. -----------------------------------隐身判定-----------------------------------
  91. /if [v_隐身]
  92. /if [(sun>39;moon>39),v_生灭予夺,(cdtime:3978;0)<1.5*gcdt]
  93. /skill 暗尘弥散
  94. /elseif [sun<11,moon<11,gcdt<bufftime:生灭予夺<10-3*gcdt,0.3<lastcast:净世破魔击<gcdt-0.2,(v_ltsm<2;v_scd>2)]
  95. /skill 暗尘弥散
  96. /elseif [nobuff:生灭予夺,(!v_生灭;v_生灭,cdtime:3978>25)]
  97. /skill [v_生灭;!v_生灭,(buff:日月灵魂>=5;buff:日月同辉)] 暗尘弥散
  98. /end
  99. /end
  100. -----------------------------光明相判定--------------------------------------
  101. /if [v_光明相]
  102. /skill [fullsun;(v_pmoon;buff:诛戮),fullmoon] 光明相
  103. /end
  104. -------------------------------生灭判定--------------------------------------
  105. /if [v_生灭予夺,gcd<0.4,(v_ltsm<2;v_scd<2*gcdt+gcd)]
  106. /if [bufftime:暗尘>gcd+0.2,0<lastcast:净世破魔击<gcdt,cdtime:暗尘弥散>40]
  107. /skill 3978
  108. /elseif [sun<=35,moon<=35,(buff:日月灵魂;0)<4]
  109. /skill [cdtime:暗尘弥散>10;banskill:暗尘弥散] 3978
  110. /end
  111. /end
  112. -----------------------------------------------------------------------------
  113. /if [v_腰坠开关,threat<=1,(tar:boss;tname:木桩|木武童|木小呆;tmaxlife>3000000),!v_banfull]
  114. /skill [(sklv:5979=1,sktest:3979,buff:6277=5);bufftime:4056>8|4246>5|2570>8|4759>10] 腰坠
  115. /end
  116. /return [ggcd>0.13] --公共cd返回
  117. -----------------------------------------------------------------------------
  118. /if [v_扶摇模式=1]
  119. /skill [tname:王翦,0.5<tlife<0.8;tname:地字一号,tlife<0.3;tname:安禄山,(tlife>0.7;tlife<0.13),mapc:大明宫;tname:头狼,mapc:英雄大明宫;tname:李倓,tlife>0.2;tname:独孤问俗,tlife<0.1;buff:沙暴;tname:萧沙;tname:沙叱博,tlife<0.32;tname:无名,tbuff:白昼;tprepare:狼之怒|雷涌|震地颤城锤|飞云回转刀|藏离精失] 9002
  120. /end
  121. /if [v_寒月耀]
  122. /skill [tpre:龙甩尾|天音化物|无懈可击|怒吼|雨钓江秋|阴阳双流|火舞金钢|噬血影|净与无净|喝酒|扫尾|吸取内力|无影击|一阳指·二品|急行军;tpre:蚀心引>0.5,tnobuff:蚀心引护盾;tpre:骑军令,tnobuff:铁盾] 寒月耀
  123. /end
  124. --------------------------------------------------------------------------------------
  125. /if [tarback,!v_天地推迟同辉]
  126. /if [(fullsun;fullmoon),buff:日月灵魂=7,nobuff:生灭予夺;bufftime:日月灵魂<1]
  127. /skill [moonhit>sunhit;v_循环选择=2;moon>sun;buff:生灭予夺,moon=sun] 幽月轮
  128. /skill [sunhit>=moonhit;sun>moon] 赤日轮
  129. /end
  130. /end
  131. ---------------------------------------------------------------------------------------
  132. /if [fullsun,!v_banfull]
  133. /return [tbuff:7423]
  134. /skill [v_循环选择=2] 生死劫
  135. /skill [v_循环选择=1] 净世破魔击
  136. /return [dis<8]
  137. /elseif [fullmoon,!v_banfull]
  138. /return [tbuff:7423]
  139. /skill [v_月劫=2] 生死劫
  140. /skill [v_月劫=1,nostate:jump&float,tnopre:骨牢|皇之怒|云烟卷|狼之怒|藏离精失] 净世破魔击
  141. /return [dis<8]
  142. /end
  143. /skill 驱夜断愁
  144. /skill [v_pmoon,(tnobuff:烈日,tar:boss;v_banfull)] 烈日斩
  145. /if [bufftime:生灭予夺>gcdt+0.13,v_ltsm>0,v_循环选择=1,temdis:5<2]
  146. /if [v_ltsm=1]
  147. /skill [((tbufftime:烈日;0)<1;(tmbufftime:灼烧;0)<1),moon<52,sun>40] 烈日斩
  148. /skill [sun>52,moon<51] 赤日轮
  149. /skill [moon<80] 银月斩
  150. /skill 幽月轮
  151. /elseif [v_ltsm=2]
  152. /skill [sun<11,moon<11,0<lastcast:净世破魔击<1] 烈日斩
  153. /skill [sun<11,moon<11,0<lastcast:净世破魔击<1] 银月斩
  154. /skill [sun>60>moon] 赤日轮
  155. /skill [moon>60>sun] 幽月轮
  156. /skill 烈日斩
  157. /skill 幽月轮
  158. /end
  159. /elseif [v_cycle=1]
  160. /skill [moon>80,(buff:日月灵魂;0)<6] 幽月轮
  161. /skill 银月斩
  162. /skill 幽月轮
  163. /elseif [v_cycle=2]
  164. /skill [tname:独孤问俗,tlife<0.4] 烈日斩
  165. /skill [emdis:5>3,v_煌日照] 煌日照
  166. /skill [temdis:4>1,sklv:5971=1] 赤日轮
  167. /skill 烈日斩
  168. /skill 赤日轮
  169. /end
  170. /skill [dis>6] 银月斩

定制补丁- 收起

-----------------卡GCD版换武器补丁--------------------------------
/var [3]v_al --定义提前补buff的gcd数，整数，最大为6
/omwp [(v_h=3;v_h=4,buff:6394),(bufftime:4761>=v_al*gcdt,buff:4761=10;gcd<1/16,v_dis4);v_h=2,buff:6394]黄泉刀 --普通武器
/omwp [v_h>2,((bufftime:4761;0)<v_al*gcdt;(buff:4761;0)<10),(gcd>=1/16;!v_dis4)]枭心之戮 --水特效武器
/omwp [v_h=2,nobuff:6394;v_h>3,(bufftime:4761>=v_al*gcdt,buff:4761=10;gcd<1/16,v_dis4),(nobuff:6394;v_h=5)]清风断川 --雷特效武器
/skill [0<bufftime:4761<gcdt,gcd=0,dis>6,cd:银月斩,fight]虹气长空


---------------------------换项链补丁-----------------------
#VarBool v_自动换项链,Icon:2833 --头部
----------主体部分--项链名称自行修改-------------------------
/if [v_自动换项链]
/equip [nofight,buff:暗尘弥散,nobuff:6394] 灵霄飘雪链 --雷特效项链
/equip [nofight,buff:暗尘弥散,buff:6394] 遮那象星环 -- 普通项链
/end
--换项链部分结束
-----------说明：雷特效项链与雷特效武器冲突，不可共用---------------


-----------------------换腰坠补丁-----------------------------------
#VarBool v_换腰坠开关,Icon:2840 --头部
----------主体部分--------------------------------------------------
/if [v_换腰坠开关]
/if [fight,icdtime:犹关坠>178]
/var [nowtime]v_换腰坠
/end
/equip [nofight,nowtime>v_换腰坠+135]犹关坠
/equip [nofight,nowtime<v_换腰坠+55] 千重腰坠
/end
--------------------------------------------------------------------
-------------------程武补丁--------------------------------

/if [buff:4930]
/if [fullsun,!v_banfull]
/skill [v_循环选择=2]生死劫
/skill [v_循环选择=1]净世破魔击
/return [dis<8]
/elseif [fullmoon,!v_banfull]
/skill [v_月劫=2]生死劫
/skill [v_月劫=1,nostate:jump&float,tnopre:骨牢|皇之怒|云烟卷|狼之怒|藏离精失]净世破魔击
/return [dis<8]
/end
/skill [!sktest:驱夜断愁,sun<80,moon<80]暗尘弥散
/skill 驱夜断愁
/skill [v_cycle=1] 银月斩,幽月轮
/skill [v_cycle=2] 烈日斩,赤日轮
/return [dis<8]
/end
-----------------------------------------------------------

更新日志- 收起

5月21日
默认普通武器改为大首领
王翦内功免疫时满日月停手
--------------------------------------------
5月16日
关于雷狼扶摇与贪魔体的抉择问题修改
-------------------------------------------
5月11日
自动纯日群怪切换条件增加奇穴检查
无往不复奇穴不再自动纯日
--------------------------------------------
5月5日
添加雷狼封岳读条后跳
--------------------------------------------
5月1日
修改天狼战禁用扶摇方式，更加严格
---------------------------------------------
4月30日
修复秘籍不对情况下生灭不使用问题
加入对阴阳易伤的检查，影响循环技能比

-----------------------------------------------
4月29日
无往不复与生灭奇穴组合循环更新
---------------------------------------
4月27日
加入贪魔体开关，关闭后附带直接取消贪魔体功能
---------------------------------------
4月23日
循环细节调整
----------------------------------------
4月21日
更新3.0版本，新混合循环
----------------------------------------
4月16日
移除了一些没必要存在的东西
-----------------------------------------
4月13日
曹炎烈定制移除，据说很坑
建议手动切换循环开关
------------------------------------------
3月31日
修正一个历史遗留的BUG
-----------------------------------------
3月27日
主月单点循环在点出洞若观火奇穴情况下禁用生死劫破魔
曹炎烈补丁正式加入主宏
------------------------------------------
3月18日
主宏换武器补丁换为旧版
卡gcd版放入定制补丁区
头部说明重写
-------------------------------------------
3月12日
针对独孤问俗的修改
--------------------------------------------
3月7日
只是改了一些喊话而已，不要在意细节
--------------------------------------------------
3月6日
水特效叠加缓冲时间改为3个gcd
--------------------------------------
2月27日
重新优化水特效武器叠加
---------------------------------------
2月24日
取消剑圣目标保护
修改水特效武器叠加方式
-----------------------------------------
2月23日
生灭流隐身时机调整
------------------------------------------------
2月21日
换武器模块微调
生灭流循环微调，纯日模式下银月斩插入
-------------------------------------------
2月16日
更新换武器模块，添加喊话
----------------------------------------
2月13日
加入自动QTE，三段加速下循环插入银月斩
---------------------------------------
1月17日
调整日月模式检查
生灭极限月循环不再在有大师队友条件下使用
---------------------------------
1月12日
修正生灭的开关图标问题
----------------------------------
1月4日
修正光明相非战斗开启bug
---------------------------------------
12月30日
迎接跨年，换了个高大上的新图标
----------------------------------------
12月29日
天狼战强行移除扶摇buff
目标仇恨识别参数命令更新
---------------------------------------
12月27日
修改目标数量检查方案为temdis
------------------------------------
12月25日
修复循环判断失效的BUG
月劫开关回归
双驱移除
-------------------------------------
12月21日
循环选择改为打完一轮能量再自动选择
增加曹炎烈模块至补丁区
-------------------------------------
12月20日
循环选择开关简化，日月循环根据目标类型和状态智能选择，可手动切换至纯月单体输出模式
月劫开关移除，自动识别六道天
换武器模块加入主宏
----------------------------------
12月18日
重写奇穴和秘籍检查
群攻部分加入目标数量判断

---------------------------------------------
12月15日
加入关键PVE奇穴检查
----------------------------------------------
12月13日
部分判定重写，据说更科学了

-----------------------------------------------
12月12日
智能扶摇整合
----------------------------------------------
12月11日
重新微调隐身和生灭判定相关
定制补丁说明更新
-----------------------------------------------
12月10日
精简主宏，附加功能换武器，换项链移至定制补丁
添加试练之地补丁，程武补丁，智能扶摇补丁

生灭流起手双驱方式微调
添加tarback判定，最低版本需求更新
------------------------------------------------
12月7日
修正生灭使用判定
分类：明教宏 焚影宏
标签：
标识：/cloud/2931
的全部作品：
  • 焚影超级宏 by 跃冰
  • 明尊超级宏 by 跃冰
  • 明教试练之地专用宏 by 跃冰
  • 焚影新手上路版-by 跃冰
  • 明尊超级宏 开关精简版
  • 焚影宏逐鹿中原测试版 BY 跃冰

    • 超级宏首页

    相关手册

    超级宏暂时已无法使用，本版仅供参考。