莫相离自己用的
云端ID 31909 作  者 最近更新20140621 代码类型超级宏 本周热度7 作者专栏
<一定要点这复制宏代码> 
  1. #name 易经宏
  2. #tip 作者：萧青荷/电六N合一。一个专业奶秀写的易经宏，需要修改自行看注释，如有问题请密我QQ/YY或者直接来电六密我。
  3. #hello $name，欢迎使用超级宏，目前版本为33.6，如有问题请在超级宏官网找我的联系方式。电六N合一【花家】诚招犀利小伙伴。
  4. #icon 4930
  5. --因使用预判，所以需控制每帧宏运行次数，否则预判会乱
  6. #delay 1
  7. #VarNum v_补一次扶摇,2,tip:补扶摇,tip_1:开启后补一次扶摇,tip_2:正常,icon_1:3751,icon_2:3752
  8. #VarBool v_自动使用腰坠,tip:特效腰坠,tip_1:使用腰坠,tip_2:不使用腰坠,icon:2841
  9. #VarNum v_预判开关,2,tip:预判开关,tip_1:开启预判,tip_2:关闭预判,icon_1:6016,icon_2:1817
  10. #VarNum v_小怪处理,2,tip:小怪处理,tip_1:小怪可开爆发,tip_2:小怪不开爆发,icon_1:5356,icon_2:1817
  11. #VarNum v_爆发模式,4,tip:爆发模式,tip_1:三层众嗔开爆发,tip_2:自动爆发,tip_3:辅助开腰坠,tip_4:不开爆发,icon_1:5397,icon_2:5396,icon_3:5399,icon_4:1817
  12. #VarNum v_金刚怒目,2,tip:金刚怒目模式,tip_1:全程保持,tip_2:百分之三十血不打金刚怒目,icon_1:440,icon_2:1817
  13. #VarNum v_副本定制,3,tip:副本定制,tip_1:开,tip_2:关,tip_3:全程扶摇,icon_1:4544,icon_2:4553,icon_3:3549
  14. #VarNum v_橙武模式,2,tip:橙武buff使用,tip_1:韦陀拿云交替,tip_2:无限韦陀,icon_1:428,icon_2:419
  15. #varnum v_自动换武器,9,tip:换武器,tip_1:没武器可换,tip_2:水切换,tip_3:雷切换,tip_4:水雷三刀,tip_5:破切换,tip_6:破雷三刀,tip_7:CW辅助,tip_8:CW辅助水三刀,tip_9:CW辅助破三刀,icon_1:5935,icon_2:3976,icon_3:4779,icon_4:4930,icon_5:2885,icon_6:2467,icon_7:3112,icon_8:2466,icon_9:3962
  16. #skillbox 韦陀献杵,无相诀,擒龙诀,亦枯亦荣,横扫六合,捉影式,扶摇直上,般若诀,锻骨诀
  17. --★打断模式开关★
  18. --1:打断
  19. --2:不打断
  20. /var [1] v_自动打断
  21. /inter [!buff:芙蓉出水宴;bufftime:芙蓉出水宴<1800] 芙蓉出水宴
  22. --★守缺优先开关★
  23. --守缺优先级正式丢出开关（再加开关开关就太多了，这个应该不常调）
  24. --1:非三豆先横扫后守缺
  25. --2:非三豆优先守缺
  26. --3:两豆不丢守缺
  27. --4:三豆丢守缺
  28. /var [sklv:业力>0,sklv:幻身>0,1;2] v_守缺优先
  29. --★通用变量★
  30. --目标类型为BOSS的怪物判定为BOSS，其他为小怪
  31. /if [target:boss;v_小怪处理=1;tname:木桩;tmaxlife>=5000000]
  32. /var [false] v_小怪判定
  33. /else
  34. /var [true] v_小怪判定
  35. /end
  37.  
  39. --横扫有效攻击距离
  40. /var [5] v_横扫距离
  41. --禁韦陀判定，点了断灭，并且目标周围有不能群的小怪
  42. /var [false] v_禁断灭
  43. --禁亦枯亦荣判定，在无法造成伤害时，不使用亦枯亦荣
  44. /var [tbuff:我流|御体|海纳百川|盾|极恶金身] v_禁亦枯亦荣
  45. --禁横扫判定，自身周围有不能群的小怪
  46. /var [false] v_禁横扫
  47. --禁攻击判定，目标不能打，自动停手
  48. /var [false] v_禁攻击
  49. --禁爆发判定，目标身上有吸伤害盾/无敌buff等
  50. /var [false] v_禁爆发
  51. --禁扶摇判定，部分BOSS不补扶摇
  52. /var [false] v_禁扶摇
  53. /if [!fight;!v_雷触发时间]
  54. /var [0] v_雷触发时间
  55. /end
  56. /if [!fight;!v_CW触发时间]
  57. /var [0] v_CW触发时间
  58. /end
  59. --雷buff内置CD,可调整
  60. /var [60] v_雷buff内置CD
  61. --上一次触发雷buff的时间，用于智能爆发
  62. /if [buff:4759,(!v_雷触发时间;nowtime-v_雷触发时间>16)]
  63. /var [nowtime] v_雷触发时间
  64. /end
  65. --CWbuff内置CD,可调整
  66. /var [30] v_CWbuff内置CD
  67. --上一次触发CWbuff的时间，用于智能爆发
  68. /if [buff:1919,(!v_CW触发时间;nowtime-v_CW触发时间>7)]
  69. /var [nowtime] v_CW触发时间
  70. /end
  71. --★自动QTE★
  72. /skill QTE
  73. --★检测换武器模式★
  74. --1.CW模式下,CW作为主武器进行输出,在GCD时换雷武器打六合棍触发雷buff,仅适用于CW与雷武器的切换
  75. --2.雷普通武器模式下,正常情况下使用普通武器进行输出,在雷的内置CD到的时候使用雷武器进行输出并触发雷buff,适用于雷-普通武器切换及三刀流
  76. /if [!fight]
  77. /var [false] v_CW雷武器模式
  78. /end
  79. /if [v_自动换武器=3]
  80. --雷武器切换
  81. /if [bag:燃木|龙木金藤|断情渡生;equip:燃木|龙木金藤|断情渡生]
  82. /var [true] v_CW雷武器模式
  83. /end
  84. /end
  85. --★换武器，如嫌繁琐，请自行将自己没有的武器删掉★
  86. /if [v_自动换武器=2]
  87. /if [buff:水·痛切<10;cd0>0.2+ping;bufftime:水·痛切<=2]
  88. /omwp 禅心伏明
  89. /else
  90. /omwp 白塔思,殷武棍,菩提擀面杖·火候,丙涅禅杖,禅机棍,碎微尘,寂净谛观,顽石问路,心禅,惟清·木缪杖,杳冥棍,枕维棍,霸王之道,摩诃萨,法界真言,妙行无量,盖穹苍,龙木金藤,燃木
  91. /end
  92. /elseif [v_自动换武器=3,!v_CW雷武器模式]
  93. --普通武器/雷武器模式,正常时候使用普通武器打,雷buff内置CD到了之后再用雷武器打
  94. /if [nobuff:6394,!v_小怪判定,(v_雷触发时间=0;(nowtime-v_雷触发时间)-v_雷buff内置CD>0)]
  95. /omwp 断情渡生,碎微尘,寂净谛观,妙行无量,法界真言,盖穹苍
  96. /else
  97. /omwp 白塔思,殷武棍,菩提擀面杖·火候,丙涅禅杖,禅机棍,顽石问路,心禅,惟清·木缪杖,杳冥棍,枕维棍,霸王之道,八道皆攻
  98. /end
  99. /elseif [v_自动换武器=3,v_CW雷武器模式]
  100. --橙武雷模式:GCD的时候使用CW,其他时候打六合棍
  101. /if [nobuff:6394,cd0>0.2+ping,!v_小怪判定,(v_雷触发时间=0;(nowtime-v_雷触发时间)-v_雷buff内置CD>0)]
  102. /omwp 断情渡生,碎微尘,寂净谛观,妙行无量,法界真言,盖穹苍
  103. /else
  104. /omwp 龙木金藤,燃木
  105. /end
  106. /elseif [v_自动换武器=4]
  107. /if [buff:水·痛切<10;cd0>0.2+ping;bufftime:水·痛切<=2]
  108. /omwp 禅心伏明
  109. /elseif [nobuff:6394,!v_小怪判定,(v_雷触发时间=0;(nowtime-v_雷触发时间)-v_雷buff内置CD>0)]
  110. /omwp 断情渡生,碎微尘,寂净谛观,妙行无量,法界真言,盖穹苍
  111. /else
  112. /omwp 白塔思,禅机棍,殷武棍,顽石问路,心禅,惟清·木缪杖,杳冥棍,枕维棍,霸王之道,摩诃萨,龙木金藤,燃木
  113. /end
  114. /elseif [v_自动换武器=5]
  115. /if [cd0>0.2+ping]
  116. /omwp 焚浪天鹏之怒
  117. /else
  118. /omwp 白塔思,殷武棍,断情渡生,菩提擀面杖·火候,丙涅禅杖,禅机棍,碎微尘,寂净谛观,顽石问路,心禅,惟清·木缪杖,杳冥棍,枕维棍,摩诃萨,法界真言,妙行无量,霸王之道,盖穹苍,龙木金藤,燃木
  119. /end
  120. /elseif [v_自动换武器=6]
  121. /if [cd0>0.2+ping]
  122. /omwp 焚浪天鹏之怒
  123. /elseif [nobuff:6394,!v_小怪判定,(v_雷触发时间=0;(nowtime-v_雷触发时间)-v_雷buff内置CD>0)]
  124. /omwp 碎微尘,寂净谛观,法界真言,妙行无量,盖穹苍
  125. /else
  126. /omwp 禅机棍,顽石问路,心禅,惟清·木缪杖,杳冥棍,枕维棍,霸王之道,摩诃萨,龙木金藤,燃木
  127. /end
  128. /elseif [v_自动换武器=7]
  129. /if [nobuff:1919,(v_CW触发时间=0;(nowtime-v_CW触发时间)-v_CWbuff内置CD>0)]
  130. /omwp 龙木金藤,白骨碎云
  131. /else
  132. /omwp 断情渡生,碎微尘,寂净谛观,妙行无量,法界真言,盖穹苍,惟清·木缪杖,杳冥棍,枕维棍,霸王之道,摩诃萨
  133. /end
  134. /elseif [v_自动换武器=8]
  135. /if [buff:水·痛切<10;cd0>0.2+ping;bufftime:水·痛切<=2]
  136. /omwp 禅心伏明
  137. /elseif [nobuff:1919,(v_CW触发时间=0;(nowtime-v_CW触发时间)-v_CWbuff内置CD>0)]
  138. /omwp 龙木金藤,白骨碎云
  139. /else
  140. /omwp 断情渡生,碎微尘,寂净谛观,妙行无量,法界真言,盖穹苍,惟清·木缪杖,杳冥棍,枕维棍,霸王之道,摩诃萨
  141. /end
  142. /elseif [v_自动换武器=9]
  143. /if [cd0>0.2+ping]
  144. /omwp 焚浪天鹏之怒
  145. /elseif [nobuff:1919,(v_CW触发时间=0;(nowtime-v_CW触发时间)-v_CWbuff内置CD>0)]
  146. /omwp 龙木金藤,白骨碎云
  147. /else
  148. /omwp 断情渡生,碎微尘,寂净谛观,妙行无量,法界真言,盖穹苍,惟清·木缪杖,杳冥棍,枕维棍,霸王之道,摩诃萨
  149. /end
  150. /end
  151. /if [v_副本定制=1;v_副本定制=3]
  152. --★各副本定制★
  153. --分副本地图进行判断,避免过多无用判断造成效率降低
  154. --★秦皇陵★
  155. /if [mapc:秦皇陵]
  156. --老一,接近下P2的时候自动扶摇,躲车
  157. /skill [target:王翦,tlife>=0.5,tlife<=0.82] 扶摇直上
  158. --老四，令狐伤，横扫距离+2
  159. /if [tplate:令狐伤]
  160. /var [7] v_横扫距离
  161. /end
  162. --★风雪稻香村★
  163. /elseif [mapc:风雪稻香村]
  164. --老三，禁群攻
  165. /if [tname:黑鹰|邪影|飞禽]
  166. --不自动打满血邪影，需要打请手动
  167. /skill [tname:邪影,tlife=1] 清空目标
  168. --自动选血最少邪影
  169. /tab [tname:邪影,tlife<1] npc,lifemin
  170. --不打鸟，如需打鸟，自行手动横扫
  171. /tab [tname:黑鹰] npc
  172. --黑鹰周围有鸟自动禁用群攻
  173. /if [tar:黑鹰,temdis:6>1,sklv:断灭=1]
  174. /var [true] v_禁断灭
  175. /end
  176. /if [tar:黑鹰,emdis:5>1]
  177. /var [true] v_禁横扫
  178. /end
  179. /else
  180. --老一，老一出现时自动切换到老一身上，暗杀者并且读条无人打断时，自动使用捉影式
  181. /tab [tprepare<0.7,tplate:隐元会暗杀者,tmfront,dis>4] npc
  182. /skill [tprepare<0.7,tplate:隐元会暗杀者] 捉影式
  183. /tab [tplate:地字一号] npc
  184. /skill [tplate:地字一号,tlife<=0.3] 扶摇直上
  185. /end
  186. --★血战天策★
  187. /elseif [mapc:血战天策]
  188. --老一,小怪打断,火星自动补扶摇,跳河自动删除扶摇buff/自动锻骨诀
  189. /skill [v_自动打断=1,tprepare:急行军] 抢珠式
  190. /if [tplate:席庶云]
  191. /skill [buff:火星,!v_禁扶摇] 扶摇直上
  192. /skill [tpre:云烟卷>0.6,recipe:《达摩武诀·锻骨诀》人偶图残页] 锻骨诀
  193. /delbuff [tpre:云烟卷] 弹跳
  194. --老三,山狼曹炎烈,排云箭自动减伤
  195. /elseif [tar:曹炎烈;tplate:追命箭矢]
  196. /if [tplate:追命箭矢]
  197. /var [true] v_禁攻击
  198. /tab [tar:曹炎烈] npc
  199. /end
  200. /skill [tpre:散花排云箭>0.5] 无相诀
  201. /if [tar:曹炎烈,temdis:6>1]
  202. /var [true] v_禁断灭
  203. /end
  204. /if [tar:曹炎烈,emdis:5>1]
  205. /var [true] v_禁横扫
  206. /end
  207. --老五,雷狼沙叱博
  208. --狼之怒和藏离精失
  209. /elseif [tplate:沙叱博]
  210. /skill [(tlife<0.31;tlife>0.7,tlife<0.72;tpre:狼之怒),!v_禁扶摇] 扶摇直上
  211. /skill [tpre:狼之怒|藏离精失,state:stand|run,nobuff:镇山河&弹跳] 无相诀
  212. /skill 保存目标
  213. /tab [tplate:破釜沉舟] npc,dismin
  214. /if [tar:破釜沉舟]
  215. /var [v_破釜沉舟出现时间;nowtime] v_破釜沉舟出现时间
  216. /if [nowtime-v_破釜沉舟出现时间>0.5]
  217. /skill [nobuff:镇山河,tplate:破釜沉舟,dis<5] 后撤
  218. /end
  219. /else
  220. /var [false] v_破釜沉舟出现时间
  221. /end
  222. /skill 读取目标
  223. --老六,阿史那从礼，全程禁用扶摇
  224. /elseif [texistnpc:阿史那从礼]
  225. /var [true] v_禁扶摇
  226. /if [tar:阿史那从礼,(tbuff:天羽散;tmana>0.2,tlife<0.42,tnobuff:天佑·厚土)]
  227. /var [true] v_禁攻击
  228. /end
  229. /else
  230. --老七,黑齿元佑
  231. --自动选择距离最近的小怪，如果在小怪阶段误选黑齿元佑则自动清空目标
  232. /tab [texistnpc:黑齿元佑,tplate:黑齿卫士|黑齿巫师|黑齿祭司,tmfront] npc,dismin
  233. /skill [texistnpc:黑齿卫士|黑齿巫师|黑齿祭司,tplate:黑齿元佑] 清空目标
  234. /skill [buff:噬魄,mana<0.5,nav>0] 亦枯亦荣
  235. --老八,苏曼莎
  236. --自动选择距离最近/正面的狼牙巫医捉影式
  237. --/tab [texistnpc:杨宁,tplate:狼牙巫医,tmfront,dis<=20,dis>10]npc,dismin
  238. --/skill [tplate:狼牙巫医,dis>10]捉影式
  239. --老九,令狐伤
  240. /if [tbuff:金蛇盘巢]
  241. /var [true] v_禁攻击
  242. /end
  243. /end
  244. --★大明宫★
  245. /elseif [mapc:大明宫]
  246. --★剑圣划水模式★
  247. /if [tplate:剑圣,fight,dis>12]
  248. /skill 捕风式,捉影式
  249. /skill [nav>=3] 金刚怒目
  250. /return
  251. /end
  252. /skill [tplate:何莘涯,nobuff:镇山河,tprepare:吞云吐纳>0.7,dis<8] 后撤
  253. /skill [v_自动打断=1,tprepare:怒吼] 抢珠式
  254. /skill [fight,(tpre:皇之怒;buff:沙暴;tplate:独孤问俗,tlife<0.13;tplate:无名,tbuff:白昼;tplate:安禄山,(tlife>0.7,fight>15;tlife<0.12);tplate:头狼),!v_禁扶摇] 扶摇直上
  255. /if [tplate:？？？;tplate:无名,tbuff:荆棘,lifeleft<40000]
  256. /var [true] v_禁攻击
  257. /end
  258. /if [tar:傀儡·天]
  259. /var [6] v_横扫距离
  260. /end
  261. --★军械库★
  262. /elseif [mapc:军械库]
  263. /skill [tplate:卓力格图,nobuff:镇山河,tprepare:掷锤>0.5] 后撤
  264. --★南诏皇宫★
  265. /elseif [mapc:南诏皇宫]
  266. /if [tpre:星斗剑法;tbuff:狸型之体|致命格挡;tar:泰崇傣|段宗公,tlife<=0.1]
  267. /var [true] v_禁攻击
  268. /end
  269. /elseif [mapc:烛龙殿]
  270. /if [tbuff:铁壁]
  271. /var [true] v_禁攻击
  272. /end
  273. --★荻花圣殿★
  274. /elseif [mapc:荻花圣殿]
  275. /if [buff:痛血指;tbuff:破剑八刀]
  276. /var [true] v_禁攻击
  277. /end
  278. --★试练之地，应要求添加★
  279. --此段宏由部分和尚要求添加，原宏出自http://www.jx3pve.com/cloud/26000
  280. /elseif [mapc:试炼之地]
  281. /var [gcdt+ping] v_gcd
  282. /var [(cdtime:横扫六合>gcd;emdis:5<2),(buff:捕风式,nav<3;(buff:擒龙诀,nav<2;nav<3),gcd>0.6+ping,(bufftime:众嗔;4)>v_gcd*2,(tbufftime:普渡四方;4)>v_gcd*2)] v_捉影判定
  283. /if [nobuff:6341,nav=3,nobuff:1919]
  284. /tab [tar:十二连环坞枪兵|十二连环坞女兵|十二连环坞锤兵|十二连环坞骑兵,dis<=4,tmfront,tlife>0.3] npc,lifemin
  285. /elseif [nobuff:6341,(nav=1,cd:守缺式,nobuff:擒龙诀;nav=0,nocd:守缺式)]
  286. /tab [tar:十二连环坞枪兵|十二连环坞女兵|十二连环坞锤兵|十二连环坞骑兵,dis<=4,tmfront,tlife>0.2] npc,lifemin
  287. /elseif [buff:6341,cd:守缺式,nav<3]
  288. /tab [tar:十二连环坞枪兵|十二连环坞女兵|十二连环坞锤兵|十二连环坞骑兵,dis<=4,tmfront,tlife<0.3] npc,lifemax
  289. /else
  290. /tab [tar:十二连环坞枪兵|十二连环坞女兵|十二连环坞锤兵|十二连环坞骑兵,dis<=4,tmfront] npc,lifemax
  291. /end
  292. /if [tbufftime:自在>5,(nocd:守缺式;nav=3)]
  293. /tab [tar:九色鹿|银腹蛛王|白额虎王,tarisem,dis<=4,tmfront,(tbufftime:自在;0)<5] npc,lifemin
  294. /elseif [cd:守缺式,nav<3]
  295. /tab [tar:银腹蛛王|白额虎王,tarisem,dis<=4,tmfront,tbufftime:普渡四方<10] npc,lifemin
  296. /end
  297. /if [emdis:20>7,tbufftime:自在>5,(nocd:守缺式;nav=3)]
  298. /tab [tar:无盐寨军师,tlife>0.1,dis<=4,tmfront,(tbufftime:自在;0)<5] npc,lifemin
  299. /elseif [emdis:20<8,tbufftime:自在>5,(nocd:守缺式;nav=3)]
  300. /tab [tar:无盐寨军师,tlife>0.2,dis<=4,tmfront,(tbufftime:自在;0)<5] npc,lifemax
  301. /elseif [cd:守缺式,nav<3]
  302. /tab [tar:无盐寨军师,tlife>0.1,dis<=4,tmfront,tbufftime:普渡四方<6] npc,lifemin
  303. /end
  304. /if [nocd:捉影式,nobuff:千斤坠,!sktest:捉影式,v_捉影判定,existnpc:尸罐|帐篷|稻草人|战旗|丢失的货物<20]
  305. /skill 保存目标
  306. /tab [tar:尸罐|帐篷|稻草人|战旗|丢失的货物,4<dis<=20,tmfront] npc,dismax
  307. /skill 捉影式
  308. /skill 读取目标
  309. /end
  310. /else
  311. --需要打断的情况下抢珠
  312. /skill [v_自动打断=1,tprepare:无懈可击|天音化物|雨钓江秋|火舞金钢|阴阳双流|龙甩尾|薛家剑法] 抢珠式
  313. /end
  314. /end
  315. /if [v_补一次扶摇=1,nocd:扶摇直上,!v_禁扶摇]
  316. /skill 扶摇直上
  317. /end
  318. /if [buff:弹跳]
  319. /var [2] v_补一次扶摇
  320. /end
  321. --★自动补般若★
  322. --打伤哥不自动补
  323. /skill [!texistnpc:杨宁,nobuff:般若诀,nobuff:1919] 般若诀
  324. --危险状态下，开无相
  325. /skill [life<0.4,fight,nobuff:渊&镇山河&春泥护花&圣手织天&蝶戏水&天地低昂&舍身] 无相诀
  326. /return [!tar]
  327. --佛心好了就开
  328. /skill [fight,nobuff:九襄地玄五阵&金刚伏魔五阵&引羌笛&极乐] 佛心诀
  329. /return [v_禁攻击]
  330. --有CWBUFF，众嗔buff快断了，补众嗔（优先级第一）
  331. /skill [cdtime:守缺式<0.2,sklv:6596=1,(bufftime:众嗔;3)<2] 守缺式
  332. /skill [v_副本定制=3,!v_禁扶摇] 扶摇直上
  333. --★橙武处理★
  334. /if [v_橙武模式=2]
  335. /skill [nav=2,fight,!v_守缺优先=1] 守缺式
  336. /skill [nav=2,fight,tar,(sktest:普渡四方;distance<=5;dis<=v_横扫距离),!v_禁横扫] 横扫六合
  337. /skill [nav=2,fight,v_守缺优先=1] 守缺式
  338. --有CWBUFF，无限韦陀
  339. /skill [!v_禁断灭,buff:1919] 韦陀献杵
  340. /elseif [v_橙武模式=1]
  341. --有CWBUFF，交替韦陀拿云
  342. /skill [buff:1919,nav=3] 拿云式
  343. /skill [!v_禁断灭,buff:1919] 韦陀献杵
  344. /end
  345. --★起手处理★
  346. --开怪首先金刚怒目消耗掉豆，然后守缺式
  347. /skill [nobuff:1919,nobuff:守缺,sktest:守缺式,cdtime:守缺式<0.2,nav=3,cdtime:金刚怒目<0.2] 金刚怒目
  348. /skill [nobuff:守缺,cdtime:守缺式<0.2] 守缺式
  349. --★群攻部分★
  350. --点了断灭的情况下，如果6尺范围内的怪物超过2只，释放韦陀献杵
  351. /skill [!v_禁断灭,sklv:断灭=1,temdis:6>2,nav=3] 韦陀献杵
  352. --★腰坠★
  353. --1【智能爆发】模式下配合擒龙诀使用腰坠
  354. --2【无脑爆发】无脑使用腰坠
  355. --3【辅助开腰坠】模式下手动擒龙，见擒龙开爆发，腰坠的判定上等同于1
  356. /skill [!v_爆发模式=4,(bufftime:弱水;0)>=5,v_自动使用腰坠,!v_小怪判定] 腰坠
  357. /inter [!buff:蛊时,mana<0.1] 仙王蛊鼎
  358. --记录禅那，之所以记录禅那，是因为放了技能之后，下一个技能就已经准备好释放了，那时候判断禅那会有一定延迟
  359. /var [v_预判开关=1,nav] v_nav
  360. --★无GCD技能部分★
  361. --无相诀之后不开爆发
  362. /if [!expcast:无相诀|扶摇直上]
  363. --优先金刚怒目，后擒龙诀
  364. /skill [(v_nav,v_nav=3;!v_nav,nav=3),fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919,(v_金刚怒目=1;tlife>0.3)] 金刚怒目
  365. /var [v_nav,(sklv:金刚怒目>0,explast:金刚怒目,0;v_nav)] v_nav --释放金刚怒目之后，禅那归零
  366. --GCD在读到接近一半的时候，再开擒龙诀，此后，每次刷到一半就会回一个豆，判定可以很精确
  367. --请勿随意调整GCD的判定数据，否则会造成预判不准在非三豆的情况下打韦陀、拿云
  368. /if [!banskill:擒龙诀,cd0<0.9,cd0>0.5,fight,sktest:守缺式,cdtime:擒龙诀<0.2,!v_小怪判定,(v_爆发模式=2;v_爆发模式=1,buff:众嗔>=3)]
  369. /skill [!v_禁亦枯亦荣,(v_nav,v_nav=1;!v_nav,nav=1),fight,cdtime:亦枯亦荣<0.2,mana<0.6,nowtime-(v_终结技释放标志;2)<1.5] 亦枯亦荣,擒龙诀
  370. /skill [v_nav,v_nav<=1;!v_nav,nav<=1] 擒龙诀
  371. /end
  372. /var [v_nav,(explast:擒龙诀,3;v_nav)] v_nav --释放擒龙诀之后，禅那变成3
  373. --擒龙诀之后，如果金刚怒目好了，优先金刚怒目
  374. /skill [(v_nav,v_nav=3;!v_nav,nav=3),fight,tlife<1,sktest:守缺式,cdtime:金刚怒目<0.2,nobuff:1919,(v_金刚怒目=1;tlife>0.3)] 金刚怒目
  375. /var [v_nav,(sklv:金刚怒目>0,explast:金刚怒目,0;v_nav)] v_nav --释放金刚怒目之后，禅那归零
  376. /end
  377. --有捕风式buff或者GCD大于0.5秒的，并且可以释放捉影式的时候，释放捉影式
  378. /skill [!tplate:地字一号|隐元会暗杀者,!texistnpc:杨宁,((v_nav,v_nav<3;!v_nav,nav<3),(buff:捕风式;gcd>0.5),cdtime:捉影式<0.2)] 捉影式
  379. /var [v_nav,(explast:捉影式,v_nav+1;v_nav)] v_nav
  380. --缺蓝就不等擒龙诀，直接开亦枯亦荣了
  381. /skill [!v_禁亦枯亦荣,mana<0.15,fight,tlife<1,(v_nav,0<v_nav<=2;!v_nav,0<nav<=2),sktest:守缺式,cdtime:亦枯亦荣<0.2] 亦枯亦荣
  382. /var [v_nav,(explast:亦枯亦荣,0;v_nav)] v_nav
  383. /if [v_nav]
  384. --擒龙诀回豆的判定，如果擒龙诀buff存在的时候，擒龙诀buff的时间接近回豆的时间了，预判回1豆
  385. /var [(bufftime:擒龙诀;18)<17,(bufftime:擒龙诀*10)%15] v_擒龙诀回豆倒计时
  386. /if [v_擒龙诀回豆倒计时,( v_擒龙诀回豆倒计时<0.3),v_nav+1] --时间限制为0-1
  387. /if [!v_added] --时间段内只加一次
  388. /var [v_nav+1] v_nav
  389. /var [true] v_added
  390. /end
  391. /else --时间段外重置加法判定变量
  392. /var [false] v_added
  393. /end
  394. /end
  395. --★有GCD技能部分★
  396. --优先守缺
  397. /skill [v_守缺优先=3,cdtime:守缺式<0.2,buff:天鼓雷音阵,bufftime:天鼓雷音五阵<=1.5] 守缺式
  398. --上述技能结束之后，如果禅那大于等于3，优先拿云，之后韦陀。
  399. --判断拿云后的一豆
  400. /skill [!explast:韦陀献杵,(v_nav,v_nav>=3;!v_nav,nav>=3),tlife<=0.3,cdtime:拿云式<0.2] 拿云式
  401. /if [explast:拿云式,recipe:《龙爪功·拿云式》人偶图残页]
  402. /var [nowtime] v_终结技释放标志
  403. /end
  404. /skill [!v_禁断灭,!explast:拿云式,(v_nav,v_nav>=3;!v_nav,nav>=3),tlife>0.3,cdtime:韦陀献杵<0.2] 韦陀献杵
  405. --判断韦陀后的一豆
  406. /if [explast:韦陀献杵,recipe:《罗汉棍法·韦陀献杵》人偶图残页]
  407. /var [nowtime] v_终结技释放标志
  408. /end
  409. --★打豆技能部分★
  410. --优先守缺，然后横扫，然后普渡,恒河劫沙，然后使用捕风
  411. /skill [v_守缺优先=2; v_守缺优先=4,nav<=1] 守缺式
  412. /skill [fight,tar,(sktest:普渡四方;distance<=5;dis<=v_横扫距离),!v_禁横扫] 横扫六合
  413. /skill [v_守缺优先=1] 守缺式
  414. /skill 普渡四方
  415. /skill [!sktest:普渡四方] 恒河劫沙
  416. /skill [(!sktest:守缺式;cdtime:守缺式>1.2),tar,!sktest:普渡四方] 捕风式
  417. #net http://www.jx3pve.com/cloud/1084

							

							
							

						

						
							
						


							
							
	
							
							

							
							

							
							

							
							

						


						
			            


							

								
								分类：通用宏


									
								标签：


								
								标识：/cloud/31909							


							
							

								的全部作品：

								
  • 莫相离自己用的
    •   
							
    

			            
    

					
    

					
					
    
						

						
    
							
								
								
						
    
					
    
				
    

			
				
    
					
    
						
    超级宏首页
    

    相关手册
    

					
    
					
					
    
						
					
    

					
    
						
    超级宏暂时已无法使用，本版仅供参考。